program : programInicio decvar decfuntemp programMain

decfuntemp : decfunCodigo decfuntemp

decfuntemp : empty

programMain : programMainIni LPAREN2 estatutos RPAREN2

programMainIni : MAIN LPAREN RPAREN

programInicio : PROGRAM SVAR PUNCOM

decvar : VAR decvar2

| empty

decvar2 : tipo SVAR nomvar decvar2

| empty

nomvar : COMA SVAR nomvar

| PUNCOM

tipo : INT

| FLOAT

| CHAR

decfunCodigo : decfunCodigoIni LPAREN funpara RPAREN PUNCOM decvar LPAREN2 estatutos RPAREN2

decfunCodigoIni : MODULE funtipo SVAR

funtipo : tipo

| VOID

funpara : tipo SVAR funpara2

| empty

funpara2 : COMA tipo SVAR funpara2

| empty

estatutos : asignacion estatutos

| llamada estatutos

| lectura estatutos

| escritura estatutos

| desicion estatutos

| repeticion estatutos

| funespecial estatutos

estatutos : retorno

| empty

asignacion : SVAR EQUAL asitipos PUNCOM

asitipos : expr

asitipos : SCHAR

expr : exprCode

exprCode : expr1 exprCodeT

exprCodeT : '+' expr1 exprCodeT

| '-' expr1 exprCodeT

exprCodeT : empty

expr1 : expr2 expr1T

expr1T : '\*' expr2 expr1T

| '/' expr2 expr1T

expr1T : empty

expr2 : LPAREN exprCode RPAREN

| term

term : NINT

term : NFLOAT

term : SVAR posfun

posfun : LPAREN parametros RPAREN

| empty

parametros : asitipos parametros2

| empty

parametros2 : COMA asitipos parametros2

| empty

llamada : SVAR LPAREN parametros RPAREN PUNCOM

retorno : RETURN LPAREN asitipos RPAREN PUNCOM

lectura : READ LPAREN SVAR lectura2 RPAREN PUNCOM

lectura2 : COMA SVAR lectura2

| empty

escritura : WRITE LPAREN escritura2 escritura3 RPAREN PUNCOM

escritura2 : SSTRING

escritura2 : asitipos

escritura3 : COMA escritura2 escritura3

| empty

desicion : IF LPAREN expresion RPAREN THEN LPAREN2 estatutos RPAREN2 desicion2

desicion2 : ELSE LPAREN2 estatutos RPAREN2

| empty

repeticion : condicional

| nocondicional

condicional : DO LPAREN2 estatutos RPAREN2 WHILE LPAREN expresion RPAREN

condicional : WHILE LPAREN expresion RPAREN DO LPAREN2 estatutos RPAREN2

expresion : comp1 expresion2

expresion2 : comp2 comp1 expresion2

| empty

comp2 : AND

| OR

comp1 : asitipos comp3 asitipos

comp1 : TRUE

| FALSE

comp3 : EQ

| GT

| GE

| LT

| LE

| NE

nocondicional : FROM SVAR EQUAL expr TO expr DO LPAREN2 estatutos RPAREN2

funespecial : LINE LPAREN expr RPAREN PUNCOM

| POINT LPAREN expr COMA expr RPAREN PUNCOM

| CIRCLE LPAREN expr RPAREN PUNCOM

| ARC LPAREN expr RPAREN PUNCOM

| PENUP LPAREN RPAREN PUNCOM

| PENDOWN LPAREN RPAREN PUNCOM

| COLOR LPAREN expr RPAREN PUNCOM

| SIZE LPAREN expr RPAREN PUNCOM

| CLEAR LPAREN RPAREN PUNCOM